Запись образа Федоры на флешку

Я столкнулся с проблемой необходимости записи загрузочного образа Федоры на флешку.
Для этого я использовал следующее:

Сначала определил куда примонтирована флешка, с помощью команды:

fdisk -l

Это оказалось /dev/sdс, после этого, ввел следующую команду для записи образа:

dd if=Fedora_24.iso of=/dev/sdс bs=8M

где

Fedora_24.iso - имя образа в текущей папке

/dev/sdс - точка монтирования флешки.

Логирование работы программы

Следующий скрипт создает пакет и таблицы для записи логов.

Логи пишутся в двух режимах:
1. логи которые откатываются при откате транзакции
2. логи которые коммитятся в автономной транзакции и которые невозможно откатить.

DROP SEQUENCE seq_tbl_system_log
/
DROP SEQUENCE seq_tbl_log
/
DROP TABLE tbl_log
/
DROP TABLE tbl_system_log
/

CREATE SEQUENCE seq_tbl_system_log
/
CREATE TABLE tbl_system_log(
  id                 INTEGER CONSTRAINT pk_tbl_system_log PRIMARY KEY,
  name               VARCHAR2(30) NOT NULL CONSTRAINT un_tbl_system_log UNIQUE
)
/

CREATE SEQUENCE seq_tbl_log
/
CREATE TABLE tbl_log(
  id                 INTEGER CONSTRAINT pk_tbl_log PRIMARY KEY,
  system_log_id      INTEGER        NOT NULL,
  message            VARCHAR2(4000) NOT NULL,
  log_type_id        INTEGER        NOT NULL,
  ts                 TIMESTAMP DEFAULT SYSDATE NOT NULL,
  CONSTRAINT fk_tbl_log_tbl_system_log FOREIGN KEY (system_log_id) REFERENCES tbl_system_log (id)
)
/

CREATE OR REPLACE FORCE VIEW v_log
AS
SELECT tllg.id
     , tslg.name
     , tllg.message
     , DECODE(tllg.log_type_id, 1, 'INFO', 2, 'WARNING', 3, 'ERROR') log_type
     , tllg.ts
  FROM tbl_log tllg
       JOIN
       tbl_system_log tslg
         ON tllg.system_log_id = tslg.id
/
CREATE OR REPLACE PACKAGE pkg_log IS

PROCEDURE reg_system_log
  (p_name               IN VARCHAR2);

FUNCTION get_system_log_id
  (p_name               IN VARCHAR2)
 RETURN NUMBER;

PROCEDURE ins_log_info
  (p_system_log_id      IN NUMBER,
   p_message            IN VARCHAR2);

PROCEDURE ins_log_info_autonomous
  (p_system_log_id      IN NUMBER,
   p_message            IN VARCHAR2);

PROCEDURE ins_log_warning
  (p_system_log_id      IN NUMBER,
   p_message            IN VARCHAR2);

PROCEDURE ins_log_warning_autonomous
  (p_system_log_id      IN NUMBER,
   p_message            IN VARCHAR2);

PROCEDURE ins_log_error
  (p_system_log_id      IN NUMBER,
   p_message            IN VARCHAR2);

PROCEDURE ins_log_error_autonomous
  (p_system_log_id      IN NUMBER,
   p_message            IN VARCHAR2);

PROCEDURE del_log
  (p_id                 IN NUMBER);
PROCEDURE del_log_autonomous
  (p_id                 IN NUMBER);

END pkg_log;
/

CREATE OR REPLACE PACKAGE BODY pkg_log
IS
PROCEDURE reg_system_log
  (p_name               IN VARCHAR2)
IS
BEGIN
  INSERT INTO tbl_system_log
    (id,
     name)
  VALUES(
   seq_tbl_system_log.NEXTVAL,
   p_name);
END;

FUNCTION get_system_log_id
  (p_name               IN VARCHAR2)
 RETURN NUMBER
IS
  l_id NUMBER;
BEGIN
  SELECT id
    INTO l_id
    FROM tbl_system_log
   WHERE name = p_name;

  RETURN l_id;
END;

PROCEDURE ins_log
  (p_system_log_id      IN NUMBER,
   p_message            IN VARCHAR2,
   p_log_type_id        IN NUMBER)
IS
BEGIN
  INSERT INTO tbl_log
    (id,
     system_log_id,
     message,
     log_type_id)
  VALUES(
     seq_tbl_log.NEXTVAL,
     p_system_log_id,
     p_message,
     p_log_type_id);
END;

--- INFO -----------------------------------
PROCEDURE ins_log_info
  (p_system_log_id      IN NUMBER,
   p_message            IN VARCHAR2)
IS
BEGIN
  ins_log(p_system_log_id, p_message, 1);
END;

PROCEDURE ins_log_info_autonomous
  (p_system_log_id      IN NUMBER,
   p_message            IN VARCHAR2)
IS
  PRAGMA AUTONOMOUS_TRANSACTION;
BEGIN
  ins_log(p_system_log_id, p_message, 1);
  COMMIT;
END;

--- WARNING -------------------------------
PROCEDURE ins_log_warning
  (p_system_log_id      IN NUMBER,
   p_message            IN VARCHAR2)
IS
BEGIN
  ins_log(p_system_log_id, p_message, 2);
END;

PROCEDURE ins_log_warning_autonomous
  (p_system_log_id      IN NUMBER,
   p_message            IN VARCHAR2)
IS
  PRAGMA AUTONOMOUS_TRANSACTION;
BEGIN
  ins_log(p_system_log_id, p_message, 2);
  COMMIT;
END;

--- ERROR ---------------------------------
PROCEDURE ins_log_error
  (p_system_log_id      IN NUMBER,
   p_message            IN VARCHAR2)
IS
BEGIN
  ins_log(p_system_log_id, p_message, 3);
END;

PROCEDURE ins_log_error_autonomous
  (p_system_log_id      IN NUMBER,
   p_message            IN VARCHAR2)
IS
  PRAGMA AUTONOMOUS_TRANSACTION;
BEGIN
  ins_log(p_system_log_id, p_message, 3);
  COMMIT;
END;

--- DELETE -----------------------------
PROCEDURE del_log
  (p_id                 IN NUMBER)
IS
BEGIN

  DELETE FROM tbl_log
    WHERE id = p_id;

END;

PROCEDURE del_log_autonomous
  (p_id                 IN NUMBER)
IS
  PRAGMA AUTONOMOUS_TRANSACTION;
BEGIN

  del_log(p_id);
  COMMIT;

END;

END pkg_log;
/

Определение размера таблиц

Для определения размера таблиц, я использую следующий SQL

SELECT table_name

     , TRUNC(SUM(table_size)/1024/1024)      AS table_size_meg

     , TRUNC(SUM(index_size)/1024/1024)      AS index_size_meg

     , TRUNC(SUM(lobsegment_size)/1024/1024) AS lobsegment_size_meg

     , TRUNC(SUM(lobindex_size)/1024/1024)   AS lobindex_size_meg

     , TRUNC(SUM(table_size      +

                 index_size      +

                 lobsegment_size +

                 lobindex_size)/1024/1024)   AS sum_meg

  FROM (SELECT segment_name AS table_name

             , bytes as table_size

             , 0     as index_size

             , 0     as lobsegment_size

             , 0     as lobindex_size

          FROM user_segments

         WHERE segment_type = 'TABLE'

         UNION ALL

        SELECT i.table_name

             , 0       as table_size

             , s.bytes as index_size

             , 0       as lobsegment_size

             , 0       as lobindex_size

          FROM user_indexes i

             , user_segments s

         WHERE s.segment_name = i.index_name

           AND s.segment_type = 'INDEX'

         UNION ALL

        SELECT l.table_name

             , 0       as table_size

             , 0       as index_size

             , s.bytes as lobsegment_size

             , 0       as lobindex_size

          FROM user_lobs l

             , user_segments s

         WHERE s.segment_name = l.segment_name

           AND s.segment_type = 'LOBSEGMENT'

         UNION ALL

        SELECT l.table_name

             , 0       as table_size

             , 0       as index_size

             , 0       as lobsegment_size

             , s.bytes as lobindex_size

          FROM user_lobs l

             , user_segments s

         WHERE s.segment_name = l.index_name

           AND s.segment_type = 'LOBINDEX')

 GROUP BY table_name

 ORDER BY sum_meg DESC

файл table_size.sql

Удаление дубликатов с перебивкой айдишников

Очень часто, при удалении дубликатов из таблицы, оказывается, что на нее уже ссылаются записи из других таблиц. Поэтому перед удалением. нам нужно заменить айдишники в дочерних таблицах, а потом удалять дубликаты. Для этого, я использую следующий скрипт:

DECLARE
   l_id   NUMBER;

   PROCEDURE sp_merge_ids (p_old          IN INTEGER,
                           p_new          IN INTEGER,
                           p_table_name   IN VARCHAR2)
   IS
      v_str   VARCHAR2 (2000)
                 := 'update table set column = :new where column  = :old';
   BEGIN
      FOR rw
         IN (SELECT urcs2.table_name, uccs.column_name
               FROM user_constraints urcs1
               JOIN user_constraints urcs2
                 ON urcs1.constraint_name = urcs2.r_constraint_name
                AND urcs1.table_name = UPPER (p_table_name)
                AND urcs1.constraint_type = 'P'
               JOIN user_cons_columns uccs
                 ON uccs.constraint_name = urcs2.constraint_name)
      LOOP
         EXECUTE IMMEDIATE REPLACE (REPLACE (v_str, 'table', rw.table_name),
                                    'column',
                                    rw.column_name)
            USING p_new, p_old;
      END LOOP;
   END;
BEGIN
   FOR r IN (SELECT employee_id, employee_name
               FROM tbl_employee
              WHERE ROWID NOT IN (SELECT MAX (ROWID)
                                    FROM tbl_employee
                                   GROUP BY employee_name))
   LOOP
      SELECT employee_id
        INTO l_id
        FROM tbl_employee
       WHERE employee_name = r.employee_name
         AND employee_id <> r.employee_id
         AND ROWNUM = 1;

      sp_merge_ids (r.employee_id, l_id, 'tbl_employee');

      DELETE FROM tbl_employee
            WHERE employee_id = r.employee_id;
   END LOOP;
END;
/

В этом скрипте, удаляются дубликаты из таблицы tbl_employee. Сначала в цикле мы определяем записи для удаления. С помощью селекта находим дубликат, который должен остаться и при помощи процедуры sp_merge_ids перебиваем старые айдишники в подчиненных таблицах, на новые. И в заключении удаляем запись.

Ключевое слово PRAGMA

Ключевое слово PRAGMA является директивой, которая передает некоторую управляющую информацию компилятору, но не преобразуется непосредственно в исполняемый код.

PL/SQL поддерживает следующие директивы:

AUTONOMOUS_TRANSACTION — приказывает исполнительному ядру PL/SQL выполнить
сохранение или откат любых изменений, внесенных в базу данных в текущем блоке, без воздействия на главную или внешнюю транзакцию.

EXCEPTION_INIT — приказывает компилятору связать конкретный номер ошибки
с идентификатором, объявленным в программе как исключение. Идентификатор должен соответствовать правилам объявления исключений.

DECLARE
  no_such_sequence EXCEPTION;
  PRAGMA EXCEPTION_INIT (no_such_sequence, –2289);
BEGIN
...
EXCEPTION
  WHEN no_such_sequence
   THEN
      q$error_manager.raise_error ('Sequence not defined');
END;


RESTRICT_REFERENCES — задает для компилятора уровень чистоты программного пакета (отсутствия действий, вызывающих побочные эффекты).

SERIALLY_REUSABLE — сообщает исполнительному ядру PL/SQL, что данные уровни
пакета не должны сохраняться между обращениями к ним.

Команды SQL*Plus

show all -- отображение значений всех переменных
show pagesize --отображение значения переменной pagesize
define x=10 -- присваивание пользовательской переменной Х строкового значения 10
define x -- отображение значения пользовательской переменной Х
select '&x' from dual; -- использование строкового значения переменной Х в запросе
variable x varchar2(10) -- объявление переменной привязки
begin :x := 'hello!'; end; -- присваивание переменной привязки значения
print :x -- вывод значения переменной привязки
spool report -- выходные данные сохраняются в файл report.lst
spool off -- отключение вывода данных в файл
edit -- сохраняет текущее содержимое буфера в файле afiedt.buf и открывает его на редактирование
define _editor = /bin/vi -- установка редактора по умолчанию
SQLPATH -- переменная окружения, в которой можно указать каталоги, где нужно искать скрипты
login.sql -- можно сохранить в нем настройки пользователя и он будет выполняться при каждом подключении к базе, главное чтобы он лежал или в текущем каталоге или в каталоге на который указывает переменная SQLPATH
WHENEVER SQLERROR EXIT SQL.SQLCODE - SQL*Plus прекратит работу, если после выполнения команды сервер базы данных в ответ на команду SQL или PL/SQL вернет сообщение об ошибке
WHENEVER SQLERROR SQL.SQLCODE EXIT ROLLBACK - означает, что перед завершением SQL*Plus будет произведен откат всех не сохраненных изменений данных.

С помощью SQL*Plus можно запускать пакетные программы, задавая в командной
строке аргументы и обращаясь к ним по ссылкам вида &1 (первый аргумент), &2
(второй аргумент) и т. д.

show errors -- отображает список последних ошибок
SHOW ERRORS категория [схема.]объект -- отображение списка последних ошибок по объекту. Например, чтобы просмотреть информацию о последних ошибках в процедуре
wordcount, выполните такую команду: SHOW ERRORS FUNCTION wordcount

Полный список категорий, поддерживаемых этой командой, зависит от версии СУБД,
но в него как минимум входят следующие категории:
DIMENSION
FUNCTION
JAVA SOURCE
JAVA CLASS
PACKAGE
PACKAGE BODY
PROCEDURE
TRIGGER
TYPE
TYPE BODY
VIEW

Вызов функции и присваивание значения переменной привязки:

VARIABLE words NUMBER
CALL wordcount('некоторый_ текст') INTO :words;
PRINT :words

DESCRIBE wordcount -- вывод описания объекта. В нашем случае, это функция wordcount 

Удаление дубликатов строк

Рассмотрим случай, когда у нас есть таблица T_EMP с дубликатами в поле EMP_NO.
Для удаления дубликатов из нее, нужно выполнить следующий запрос:

DELETE
    FROM t_emp
     WHERE rowid NOT IN (SELECT MAX(rowid)
                                                 FROM t_emp
                                               GROUP BY emp_no)